百科学社

  1. 数据库编程培训首页
  2. 文学教育

数据库编程培训

十万个为什么 • • 文学教育

11.嵌入式数据库管理工具开发案例(1)

11.1开发背景

随着技术的发展，Web应用不断普及的今天，小程序、手机 APP 等应用也在不断繁荣，在大众面前呈现出各式各样的客户端应用。在客户端应用中，很多时候我们需要在客户端记录一些数据，这时就会想到使用嵌入式数据库来保存或者处理这些数据了，如微信、QQ等都使用了 SQLite 数据库来处理客户端的用户数据。而我们一般情况下的软件开发流程是首先按照产品经理设计的原型来进行数据库设计，然后在数据库上创建表、视图、存储过程等。这样就需要对嵌入式数据库进行初始化，如果没有专门的工具操作嵌入式数据库，我们就只能借助于关系型数据库管理工具来完成这些操作，为了方便程序员操作独立的嵌入式数据库，开发一款嵌入式数据库管理系统还是有必要的。具体需求如下：

  • 支持 SQLite、FireBird 两种数据库
  • 可以创建数据库
  • 可以在数据库上执行 SQL 语句
  • 可以将执行的 SQL 语句保存为文件
  • 可以打开文件系统中的 SQL 文件
  • 可以记录在数据库上执行过的操作

界面设计如下图所示：

数据库编程培训

11.2 Lazarus 资源文件

对于嵌入式数据库 SQLite 来说，连接一个不存在的数据库即可创建新的数据库；而对于 FireBird 数据库来说，无法通过连接一个不存在的数据库来创建新的数据库，一般情况下，我们可以通过 isql 工具执行 create database 语句来创建数据库。

鉴于此，在我们的嵌入式数据库管理工具中实现创建数据库的方法就不能采用数据库本身提供的方法来创建新的数据库。那么，还有什么方法呢？这时候，我们自然会想到可以复制一个空数据库作为新的数据库，也就是说，我们事先分别准备一个空数据库，根据用户的需要在创建数据库的时候，直接复制即可。但这样又存在一个问题就是系统必须在发布版本中带上空数据库，而这个空数据库很容易被用户连接上以后进行各种操作，也就是说，在用户复制的时候可能已经不是空数据库了，怎么办呢？显然还是有办法的，我们可以将空数据库文件打包到 Lazarus 资源文件中，需要的复制的时候从资源文件中加载到文件系统即可。

所以，本节内容我们主要介绍 Lazarus 的资源文件的使用，然后在此基础上实现嵌入式数据库管理工具的创建数据库。

资源文件包含应编译为可执行文件的数据。这些数据可以由图像、字符串表、版本信息等组成。甚至是Windows 清单和表单。这包括程序员可以在代码中检索的数据（作为文件访问）。如果您想分发自包含的可执行文件，那么使用资源会很方便。

11.3 Lazarus 资源文件的使用

11.3.1向程序中添加资源

如果我们需要在可执行文件中存储一些数据的情况，以及在程序运行期间要从中提取这些数据。那么我们可以向程序中添加资源。

首先，我们需要告诉编译器要在资源中包含哪些文件。我们可以在一个.rc（资源脚本）文件中说明资源所包含的文件。其格式为：

<资源名称> <资源类型> <数据文件名>

如：

MYDATA RCDATA "mydata.dat"

指示编译器将资源包含到项目中，格式：

{$R <rc文件名>}

如：

program mydata;

{$R mydata.rc}
begin
end.

11.3.2在程序中使用资源文件

现在，我们将存储的资源提取到一个文件中。如：

program mydata;
uses
  SysUtils, Classes, LCLType;
{$R mydata.res}
var
  S: TResourceStream;
  F: TFileStream;
begin
  // create a resource stream which points to our resource
  S := TResourceStream.Create(HInstance, \'MYDATA\', RT_RCDATA);
  // Please ensure you write the enclosing apostrophes around MYDATA, 
  // otherwise no data will be extracted.
  try
    // create a file mydata.dat in the application directory
    F := TFileStream.Create(ExtractFilePath(ParamStr(0)) + \'mydata.dat\', fmCreate); 
    try
      F.CopyFrom(S, S.Size); // copy data from the resource stream to file stream
    finally
      F.Free; // destroy the file stream
    end;
  finally
    S.Free; // destroy the resource stream
  end;
end.

也支持直接从FPC资源加载，例如：

procedure exampleproc;
var
  Image: TImage
begin
  Image := TImage.Create;
  Image.Picture.LoadFromResourceName(HInstance,\'image\'); // note that there is no need for the extension
end;

11.4 Lazarus 资源文件使用示例

本例通过资源文件加载一张图像显示到窗体上，点击一个按钮后将数据文件提取到文件系统中。

创建一个应用，拖放一个 TImage 和 TButton

准备一种图像文件 980.jpeg 和一个可执行程序 hello.exe

新建一个文本文件并保存为 myres.rc，内容如下：

I980 RCDATA "980.jpeg"
HELLO RCDATA "hello.exe"

在应用程序中添加编译器指令：

{$R myres.rc}

在应用程序中引入如下单元：

uses LCLType;

编写窗体的 OnCreate 事件：

procedure TForm1.FormCreate(Sender: TObject);
begin
  Image1.Picture.LoadFromResourceName(HInstance, \'I980\');
end;

编写按钮的单击事件：

procedure TForm1.Button1Click(Sender: TObject);
var
  S: TResourceStream;
  F: TFileStream;
begin
  // 创建指向资源的资源流
  S := TResourceStream.Create(HInstance, \'HELLO\', RT_RCDATA);
  try
    // 创建一个文件
    F := TFileStream.Create(\'extract.exe\', fmCreate);
    try
      F.CopyFrom(S, S.Size); // 将资源流中的数据复制到文件
    finally
      F.Free; // 释放文件流
    end;
  finally
    S.Free; // 释放资源流
  end;
end;

完整的示例代码如下：

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, StdCtrls, ExtCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private

  public

  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}
{$R myres.rc}     // 编译资源文件指令

{ TForm1 }

uses LCLType;    // RT_RCDATA 所在单元

procedure TForm1.FormCreate(Sender: TObject);
begin
  Image1.Picture.LoadFromResourceName(HInstance, \'I980\');
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  S: TResourceStream;
  F: TFileStream;
begin
  // 创建指向资源的资源流
  S := TResourceStream.Create(HInstance, \'HELLO\', RT_RCDATA);
  try
    // 创建一个文件
    F := TFileStream.Create(\'extract.exe\', fmCreate);
    try
      F.CopyFrom(S, S.Size); // 将资源流中的数据复制到文件
    finally
      F.Free; // 释放文件流
    end;
  finally
    S.Free; // 释放资源流
  end;
end;

end.

11.5 创建数据库

在我们设计的主窗体中（11.1中），当单击“创建”按钮时，打开创建数据库对话框，该对话框窗体设计如下图：

数据库编程培训

窗体中组件的主要属性是数据库选项，包括：sqlite-3 和 firebird-2.5 两项。

窗体的声明代码：

TCreatedbForm = class(TForm)
    GroupBox1: TGroupBox;
    GroupBox2: TGroupBox;
    GroupBox3: TGroupBox;

    CancelButton: TButton;
    CreateButton: TButton;
    SelFileDirButton: TButton;

    FileNameEdit: TEdit;
    DBComboBox: TComboBox;
    FileDirEdit: TEdit;

    DBFileSelectDirectoryDialog: TSelectDirectoryDialog;

    procedure CancelButtonClick(Sender: TObject);
    procedure CreateButtonClick(Sender: TObject);
    procedure FormActivate(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure SelFileDirButtonClick(Sender: TObject);
  private

  public

  end;

编写窗体的 OnCreate 事件：

procedure TCreatedbForm.FormCreate(Sender: TObject);
begin
  // 组件初始化
  FileNameEdit.Text:=\'\';
  DBComboBox.ItemIndex:=0;
  FileDirEdit.Text:=\'\';
end;

选择文件位置按钮的单击事件：

procedure TCreatedbForm.SelFileDirButtonClick(Sender: TObject);
begin
  // 选择数据库文件位置
  DBFileSelectDirectoryDialog.FileName:=\'\';
  if DBFileSelectDirectoryDialog.Execute then
    FileDirEdit.Text:=DBFileSelectDirectoryDialog.FileName;
end;

我们事先准备好空数据库文件：emtdb.db(SQLite3数据库)和EMTDB.FDB(FireBird2.5数据库)

新建 db.rc 文件，内容如下：

SQLite3_EMTDB RCDATA "emtdb.db"
FireBird2.5_EMTDB RCDATA "EMTDB.FDB"

在代码中添加：

{$R db.rc}

在代码引入单元：

uses LCLType;

声明提取资源文件函数：

private
     function ExtractResourceFile(ResName: String; FileName: String): Boolean;

编写提取资源文件函数代码：

function TCreatedbForm.ExtractResourceFile(ResName: String; FileName: String): Boolean;
var
  S: TResourceStream;
  F: TFileStream;
begin
  Result:=False;
  // 创建指向资源的资源流
  S := TResourceStream.Create(HInstance, ResName, RT_RCDATA);
  try
    // 创建一个文件
    F := TFileStream.Create(FileName, fmCreate);
    try
      if F.CopyFrom(S, S.Size) = S.Size then Result:=True; // 将资源流中的数据复制到文件
    finally
      F.Free; // 释放文件流
    end;
  finally
    S.Free; // 释放资源流
  end;
end;

编写创建按钮的单击事件：

procedure TCreatedbForm.CreateButtonClick(Sender: TObject);
var
  ResourceName: String;
  TargetFile: String;
begin
  // 创建
  if DBComboBox.ItemIndex < 0 then
  begin
    MessageDlg(\'提示\', \'请选择数据库！\', mtInformation, [mbOK], 0);
    Exit;
  end;

  if FileDirEdit.Text = \'\' then
  begin
    MessageDlg(\'提示\', \'请设置数据库文件位置！\', mtInformation, [mbOK], 0);
    Exit;
  end;

  if FileNameEdit.Text = \'\' then
  begin
    MessageDlg(\'提示\', \'请设置数据库文件名！\', mtInformation, [mbOK], 0);
    Exit;
  end;

  if not DirectoryExists(FileDirEdit.Text) then
  begin
    MessageDlg(\'提示\', \'您设置的数据库文件位置不存在，请重新设置！\', mtInformation, [mbOK], 0);
    FileDirEdit.Text := \'\';
    Exit;
  end;

  TargetFile := FileDirEdit.Text + \'/\' + FileNameEdit.Text;
  if DBComboBox.Text = \'sqlite-3\' then
  begin
    ResourceName:=\'SQLite3_EMTDB\';
    if ExtractFileExt(TargetFile) = \'\' then TargetFile := TargetFile + \'.db\'
  end;
  if DBComboBox.Text = \'firebird-2.5\' then
  begin
    ResourceName:=\'FireBird2.5_EMTDB\';
    if ExtractFileExt(TargetFile) = \'\' then TargetFile := TargetFile + \'.fdb\'
  end;

  if FileExists(TargetFile) then
    if MessageDlg(\'文件已存在，覆盖吗？\', mtConfirmation, [mbYes, mbNo], 0) = mrNo then Exit;


  if ExtractResourceFile(ResourceName, TargetFile) then
  begin
    MessageDlg(\'提示\', \'数据库创建成功！\', mtInformation, [mbOK], 0);
    Close;
  end
  else
    MessageDlg(\'提示\', \'数据库创建失败！\', mtInformation, [mbOK], 0);
end;




免责声明
    以上文章转载自互联网，文章内容仅供参考，不构成建议，也不代表百科学社赞同其观点。如有侵权请联系755934052@qq.com，提供原文链接地址以及资料原创证明，本站将会立即删除
十万个为什么十万个为什么网站编辑

相关推荐

  • 关于消防的知识有哪些(有关消防的知识)

    公共场合、办公区域、仓储物资、车辆维护防火要点有哪些？这些消防知识请牢记！（自然资源部 ）

    十万个为什么十万个为什么
    2022年07月23日 • 文学教育
  • 空调启动 文学教育

    空调启动

    海尔中央空调打开方法如下：在室内机外壳面板打开后，右边靠电气部品箱上有个手调机。在急着使用空调机，却临时找不到遥控器的时候可以采用。开关控制面板使用方法：开关-就是开关机；模式-转换运行模式（制冷、制热、通风、除湿等）；温度-是调整温度高低调整；水泵-控制循环水泵；设定-用来设定时间和定时时间（和定

    十万个为什么十万个为什么
    2022年07月23日
  • xml文件是啥(xml文件如何完整打开) 文学教育

    xml文件是啥(xml文件如何完整打开)

    概念XML名为可扩展标记语言，与HTML结构类似。用途用于结构化存储、传输数据。语法例子：

    十万个为什么十万个为什么
    2022年07月23日
  • 粉底液跟粉饼的区别(粉饼和粉底液的区别和作用) 文学教育

    粉底液跟粉饼的区别(粉饼和粉底液的区别和作用)

    很多人日常会使用粉底液或者粉饼来上妆，但是相信也有一部分人是不知道这两种有什么区别的。事实上，粉底液和粉饼是两款完全不同的底妆产品，那么究竟具体区别在哪里呢。　　一、粉底液和粉饼的区别　　1、粉底液是十分容易上脸和涂抹均匀的，可以很好地使得妆容变得自然和立体，也可以使得粉状以及彩妆保持更加久。　　2

    十万个为什么十万个为什么
    2022年07月23日

  • 个人成长文章(关于成长的经典散文)

    ​​​​大家好:首先呢我介绍一下我自己，我是一位来自农村的河南90后小伙。可能文章有点长，大家看完之后看看有没有跟我有相同之处。下面就开始介绍了，我呢，从小家里就不富裕，兄弟姊妹也多。属我最小。自从05年不上学后就第一次开始出去打工，那时候刚刚退学，在家待着也没有小伙伴跟我玩，无聊啊，就出去去天津打

    十万个为什么十万个为什么
    2022年07月23日 • 文学教育

版权声明：本文内容由互联网用户自发贡献，该文观点仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌抄袭侵权/违法违规的内容， 请通知我们，一经查实，本站将立刻删除。